Import Tcl 8.5.15 (as of svn r89086)

tests/pid.test

@@ -0,0 +1,57 @@
+# Commands covered:  pid
+#
+# This file contains a collection of tests for one or more of the Tcl
+# built-in commands.  Sourcing this file into Tcl runs the tests and
+# generates output for errors.  No output means no errors were found.
+#
+# Copyright (c) 1991-1993 The Regents of the University of California.
+# Copyright (c) 1994-1995 Sun Microsystems, Inc.
+# Copyright (c) 1998-1999 by Scriptics Corporation.
+#
+# See the file "license.terms" for information on usage and redistribution
+# of this file, and for a DISCLAIMER OF ALL WARRANTIES.
+
+if {[lsearch [namespace children] ::tcltest] == -1} {
+    package require tcltest 2
+    namespace import -force ::tcltest::*
+}
+
+testConstraint pidDefined [llength [info commands pid]]
+
+test pid-1.1 {pid command} pidDefined {
+    regexp {(^[0-9]+$)|(^0x[0-9a-fA-F]+$)} [pid]
+} 1
+test pid-1.2 {pid command} -constraints {unixOrPc unixExecs pidDefined} -setup {
+    set path(test1) [makeFile {} test1]
+    file delete $path(test1)
+} -body {
+    set f [open |[list echo foo | cat >$path(test1)] w]
+    set pids [pid $f]
+    close $f
+    list [llength $pids] [regexp {^[0-9]+$} [lindex $pids 0]] \
+       [regexp {^[0-9]+$} [lindex $pids 1]] \
+       [expr {[lindex $pids 0] == [lindex $pids 1]}]
+} -cleanup {
+    removeFile test1
+} -result {2 1 1 0}
+test pid-1.3 {pid command} -constraints pidDefined -setup {
+    set path(test1) [makeFile {} test1]
+    file delete $path(test1)
+} -body {
+    set f [open $path(test1) w]
+    set pids [pid $f]
+    close $f
+    set pids
+} -cleanup {
+    removeFile test1
+} -result {}
+test pid-1.4 {pid command} pidDefined {
+    list [catch {pid a b} msg] $msg
+} {1 {wrong # args: should be "pid ?channelId?"}}
+test pid-1.5 {pid command} pidDefined {
+    list [catch {pid gorp} msg] $msg
+} {1 {can not find channel named "gorp"}}
+
+# cleanup
+::tcltest::cleanupTests
+return